Section 5 - Laboratories
The DoorLabOne is east of High Corridor. It is a door. It is openable and closed. The printed name is "[if the player is in High Corridor]east[otherwise]west[end if] glass door". Understand "glass/paneled/door/east/west/doors/w/e" as the DoorLabOne. It is scenery. The description is "[if open]It is open[otherwise]It is closed[end if]."
LabOne is east of DoorLabOne. The printed name is "East Laboratory". "A sterile room, every wall filled by glass cases of the same size and shape. It opens west through a glass paneled door."
The glass cases are scenery in LabOne. The description is "A series of glass cases covers all the walls of this tiny room. They are all dark and empty, except for a single one, whose interior is lit by a pure white strobing flash." Understand "dark" as the glass cases.
Instead of doing something except examining to the glass cases, say "They are hundreds. Focus on smaller tasks."
The lit case is scenery in LabOne. The description is "The case is filled with white light, and nothing else. It can be opened." It is a container. It is closed and openable. It is transparent. Understand "single/one/strobe/strobing/flashing/flash/white/light" as the lit case.
Instead of attacking the lit case, try attacking the glass cases.
Instead of attacking the glass cases, say "The glass is sturdy. Anyway, you don't seem to find destruction amusing."
The invisible nebula is in Hell. It is scenery. Understand "faint/buzz/buzzing/noise/wind/breath/small/insect/insects" as the invisible nebula.
Instead of doing something to the invisible nebula, say "You don't even fully [italic type]sense[roman type] the presence of that thing."
Instead of listening while the invisible nebula is visible, say "You can hear a very faint buzzing, as if a ridiculously small insect is flying nearby."
Instead of opening the lit case, say "You pull the handle, then release it. The small door closes pneumatically in a few seconds."
Instead of opening the lit case for the first time:
say "You pull the handle then release it. The small door closes back pneumatically in a few seconds.[paragraph break]Something strange happens.[paragraph break]A faint... wind caresses your right arm as the case closes. It feels like someone is breathing in your ears with levity. A sort of... buzzing can be heard around you.[paragraph break]It could easily have been your imagination.";
now the invisible nebula is in LabOne.
Every turn when the invisible nebula is visible for three turns:
say "Your head fills with a freezing sensation.[paragraph break]Within seconds, your sight blurs and a pounding noise starts whipping in your ears. You understand you are being eaten alive from the inside when you see your own face melting through your hands like dripping ice-cream.";
record "Invisible Killer" as achieved;
end the game in death.
Every turn when the invisible nebula is in LabOne for four turns:
if the DoorLabOne is open:
place invisible nebula in scope;
if the player is in LabOne:
say "The faint buzzing disappears through the open door.";
else if the player is in High Corridor:
say "You feel a small, buzzing wind passing through your hair and vanishing through the gaps in the corridor.";
now the invisible nebula is in Hell.
The DoorLabTwo is northeast of High Corridor. It is a door. It is openable and closed. The printed name is "[if the player is in High Corridor]northeast[otherwise]southwest[end if] glass door". Understand "glass/paneled/door/northeast/southwest/doors/ne/sw" as the DoorLabTwo. It is scenery. The description is "[if open]It is open[otherwise]It is closed[end if]."
LabTwo is northeast of DoorLabTwo. The printed name is "Northeast Laboratory". "The room is exceptionally blank. Its walls are lined with polished metal and there's no furniture, apart from a single, weighty table in its center."
Some metal walls are scenery in LabTwo. The description is "Plain, polished metal. No scratch, no defect, no dressing."
The weighty table is scenery in LabTwo. The description is "It looks like a metal table, but only because it is made from a horizontal slab and four legs. It is polished to exhaustion. It looks like an examination desk.[paragraph break][first time]Just by chance you drop a glance down and discover something. [only]Under the table is a steel grate, leading into darkness." Understand "slab/legs/horizontal/four/polished/examination/desk" as the weighty table.
Before examining or searching the weighty table for the first time, now the Waste Duct is apparent.
Instead of searching weighty table, say "Under the table you see a steel grate, leading into darkness."
Instead of looking under the weighty table, try searching the weighty table.
Before entering the weighty table:
say "You lie down on the table for a while. You stand back up when you begin feeling too much an experiment on a slab.";
stop the action.
The steel grate is scenery in LabTwo. It is an enterable container. The description is "It holds on heavy hinges. You can[first time] (maybe)[only] open it and check what's inside."
Instead of inserting something into the steel grate, say "The holes in the grate are too tiny. It looks like a waste of effort, anyway."
Instead of closing the steel grate, say "It is closed already."
Instead of opening the steel grate:
say "You pull up the grate and look inside. Darkness welcomes you. When you release the grate, it slowly closes back."
Instead of pulling or taking the steel grate, try opening the steel grate.
Instead of entering the steel grate:
say "You pull the grate and hold it up while you descend into darkness.";
now the player is in Waste Duct.
Instead of going down from LabTwo, try entering the steel grate.