Andromeda Apocalypse - Extended Edition — 27 of 97

Section 7 - The Power Control Room

The Power Control Room is up from Waste_west. "The large octagonal-shaped chamber is filled by a massive machine. The enormous totem has an eight-pointed star-shaped base, with a central column rising to the ceiling at least thirty meters above you. The rest of the floor is littered with metal cylinders, some of which still protrude from the machine itself[first time].[paragraph break]You remember having seen something similar at the University, in your first year by the Propulsory Science Compartment.[paragraph break][italic type]This is a power control device,[roman type] you think. [italic type]It must be part of the engines of this... station[roman type][only].[paragraph break]To the northeast, [if the glass panel is open]you can exit to the high corridor[otherwise]a glass panel overlooks the high corridor[end if]." It is southwest from the glass panel.

Instead of listening when in the Power Control Room, say "[if the Electricity is switched off]The silence is astonishing[else]The machine is humming vigorously[end if]."

The seethroughcorridor is scenery in the Power Control Room. Understand "high/corridor" as the seethroughcorridor. The description is "You can see the high corridor to the northeast."

The large octagonal-shaped machine is scenery in the Power Control Room. It is a device. It is switched off. Understand "power/control/device/enormous/totem/massive/star/eight-pointed/base/generator/accumulator" as the large octagonal-shaped machine. The description is "The giant structure is star shaped. Eight branches serve as solid legs for a large column, rising above it and diving into the ceiling. [If switched off]It is dark and inert[otherwise]It is lit by several small dots on every vertical surface[end if]. On its side, a series of round holes cut through the metal, some harboring strange, metallic cylinders."

Instead of switching on the large octagonal-shaped machine:

if the large octagonal-shaped machine is switched off:

say "You have to do something specific to turn it on. There is no shortcut.";

otherwise:

say "The machine is switched on and functioning.".

Instead of switching off the large octagonal-shaped machine:

if the large octagonal-shaped machine is switched on:

say "You have to do something specific to turn it off. There is no shortcut.";

otherwise:

say "The machine is switched off already.".

The metal column is part of the large octagonal-shaped machine. The description is "At least two meters wide, this is where energy could be convoluted when the power control device is operational. [if the large octagonal-shaped machine is switched off]It is now dark and noiseless[otherwise]Streams of energy crawl on its surface like rampaging thunder[end if]."

Instead of doing something except examining to the metal column, say "It is unreachable, as it towers above the bulky machine."

Some round holes are part of the large octagonal-shaped machine. The description is "Some of the holes harbor strange metallic cylinders, while others rest empty." Understand "hole" as the round holes.

After examining the round holes for the first time:

say "One of the holes, scratched and punctured, catches your attention. It contains a crumpled, rusty cylinder, broken in half by some mysterious force.";

now the scratched hole is in the Power Control Room.

Instead of searching the round holes, try examining the round holes.

The scratched hole is a container. It is fixed in place. "On the power control device is a scratched and punctured hole." The description is "This particular hole has sustained major damage." Understand "bay/scratch/scratches" as the scratched hole.

In the scratched hole is a broken cylinder. The description of the broken cylinder is "The object has been pierced by some unknown force and now lies broken in half and useless." Understand "crumpled/pierced/rusty" as the broken cylinder.

Instead of inserting something into the scratched hole, say "It doesn't look like a storage facility, but a very precise and purposefully designed bay. You may find other, more useful things to fit it."

Some metal cylinders are scenery in the Power Control Room. The description is "Several, scattered cylinders litter the floor and pop out from some of the round holes in the massive machine. They all look dead and unusable."

Instead of taking the metal cylinders, say "They are heavy and useless."

[After examining the metal cylinders for the first time:

say "Among the debris, you scout a cylinder that looks not-dead-yet.";

now the silver cylinder is in the Power Control Room;

try looking.]

The silver cylinder is a closed openable container in the Power Control Room. "Among the equipment pieces littering the floor, you scout an unscarred, silver cylinder." The description is "A silver cylinder, unscarred.[if charged] It faintly vibrates at the touch.[end if] A cap [if closed]closes its top[otherwise]is open on its top[end if]." Understand "unscarred/cap/vibrating" as the silver cylinder.

Before searching the silver cylinder:

if the silver cylinder is open:

say "There is a concave space inside the cylinder. It looks like it can host a series of rectangular panels, or a cube of sorts.".

Instead of inserting something into the large octagonal-shaped machine:

if the scratched hole is in the Power Control Room:

try inserting the noun into the scratched hole;

otherwise:

say "There are too many holes in the machine. Maybe you want to better examine them.".

Instead of inserting something into the metal column, try inserting the noun into the large octagonal-shaped machine.

Instead of inserting something into the round holes, try inserting the noun into the large octagonal-shaped machine.

[Check inserting something into the silver cylinder:

if the silver cylinder is closed:

try opening the silver cylinder.]

Instead of inserting the plutonium battery into the silver cylinder:

if the silver cylinder is open:

say "You try and put the [plutonium battery] in the cylinder... and it fits wonderfully.";

now the plutonium battery is in the silver cylinder;

now the cylinder is charged;

else:

say "The [silver cylinder] is closed.".

Instead of removing the plutonium battery from the silver cylinder:

if the silver cylinder is open:

say "You pick up the [plutonium battery] from the cylinder.";

now the player carries the plutonium battery;

now the cylinder is depleted;

else:

say "The [silver cylinder] is closed.".

Instead of inserting something into the silver cylinder:

if the silver cylinder is open:

say "You may want to feed something more... energetic to the cylinder.";

else:

say "The [silver cylinder] is closed.".

Instead of inserting the silver cylinder into the scratched hole:

if the scratched hole contains something (called the clogger):

say "[The clogger] is in the hole at the moment. You may want to remove it, first.";

stop the action;

else if the cylinder is depleted:

say "You put the cylinder in the round hole. Nothing obvious happens. You take it back.";

else if the steel valve is charged:

say "You put the cylinder in the round hole. Nothing obvious happens. You take it back.";

else:

say "As you fit the powered cylinder into the bay, the machine starts vibrating. In a matter of seconds, it starts roaring as if a thousand wasps are struggling to escape from its belly. Finally, electric arcs start running through the high column's surface and the machine reaches full potential.";

now the silver cylinder is in the scratched hole;

now the large octagonal-shaped machine is switched on;

now Electricity is switched on;

now the glass panel is apparent;

if the glass panel is closed:

say "[line break]After a while, the darkened glass panel closing the northeast exit slides into the wall, disappearing.";

now the glass panel is open.

Every turn when the glass panel is open for the first time:

record "To Shed a Light" as achieved.

Instead of removing the silver cylinder from the scratched hole:

if the cylinder is depleted:

say "You pull off the cylinder.";

now the silver cylinder is carried by the player;

else if the steel valve is charged:

say "You pull off the cylinder.";

else:

say "As you remove the cylinder from its bay, the machine quickly stops and returns to sleep.";

now Electricity is switched off;

now the large octagonal-shaped machine is switched off;

now the silver cylinder is carried by the player.

Instead of taking the silver cylinder when the silver cylinder is in the scratched hole: try removing the silver cylinder from the scratched hole.

Does the player mean doing something to the silver cylinder when the silver cylinder is carried by the player: it is very likely.

Does the player mean inserting the plutonium battery into the silver cylinder: it is very likely.

Does the player mean doing something to the broken cylinder when the player is not in The Radio: it is very likely.