Andromeda Apocalypse - Extended Edition — 29 of 97

Section 9 - The Train Station

The Train Station is north of High_corr_N. "[first time]You leave the cold environment of the corridors to enter a much wider space.[paragraph break][only]Light in here gets dimmer, as the only source is several meters up ahead, on the distant ceiling. In front of you, a ramp runs into several tunnels, each lined by railways. Many of the holes are shuttered by heavy bulkheads, while others lead into darkness, way out of reach. On the opposite side, the circular room enters the high corridor to the south." It is in the dark corridors.

The ramp is scenery in the Train Station. The description is "A set of rails forking and jumping into each of the tunnels up above[first time]. You guess this must be a sort of a train hub, where wagons depart and collect[only]."

Instead of entering the ramp, say "The ramp is too steep to climb."

Instead of climbing the ramp, try entering the ramp.

Some dark tunnels are scenery in the Train Station. The description is "The tunnels leave the room in every direction. Some are closed, others are open but horribly dark." Understand "rails/railways/holes/bulkheads" as the dark tunnels.

Instead of entering or climbing the dark tunnels, say "They are way out of reach."

Instead of inserting something into the dark tunnels, say "The nearest ones are closed. The rest is too far to reach."

The lone wagon is fixed in place in the Train Station. "A lone wagon, an open boat hanging over rails, sits undamaged at the [if the location is Train Station]beginning[else]end[end if] of the ramp." It is an enterable supporter. The description is "A means of transport, by any chance." Understand "open/boat" as the lone wagon. The lone wagon can be lonely_s or lonely_n or inhabited. The lone wagon is lonely_s.

On the lone wagon is a rusty console. It is fixed in place. The description is "On the console is a set of devices. The most striking are a red and a brown button. The first points north, while the latter points south." Understand "devices/set" as the rusty console.

Instead of climbing the lone wagon, try entering the lone wagon.

The red button is part of the rusty console.

Instead of pushing the red button:

if the Electricity is switched off:

say "You push the button, but nothing happens. It looks like it needs powering.";

otherwise:

if the lone wagon is in the Train Station:

say "The wagon departs![paragraph break][if the player is on the lone wagon]After a short while you find yourself in...[end if]";

now the lone wagon is in the Crossroads;

if the player is on the lone wagon:

now the lone wagon is inhabited;

try looking;

stop the action;

else if the lines button is plus_shaped and the lone wagon is in the Crossroads:

say "The wagon departs![paragraph break][if the player is on the lone wagon]After a short while you find yourself in...[end if]";

now the lone wagon is in the Second Station;

if the player is on the lone wagon:

now the lone wagon is lonely_n;

try looking;

stop the action;

otherwise:

say "Nothing happens. The wagon has reached the destination.".

Every turn when the lone wagon is in the Crossroads for four turns:

if the lone wagon is lonely_s:

now the lone wagon is in the Train Station;

if the player is in Train Station:

say "The wagon reappears from the north and brakes in front of you.";

else if the lone wagon is lonely_n:

now the lone wagon is in Second Station;

if the player is in Second station:

say "The wagon reappears from the south and brakes in front of you.".

The brown button is part of the rusty console.

Instead of pushing the brown button:

if the Electricity is switched off:

say "You push the button, but nothing happens. It looks like it needs powering.";

otherwise:

if the lone wagon is in the Second Station:

say "The wagon departs![paragraph break][if the player is on the lone wagon]After a short while you find yourself in...[end if]";

now the lone wagon is in the Crossroads;

if the player is on the lone wagon:

now the lone wagon is inhabited;

try looking;

stop the action;

else if the lone wagon is in the Crossroads:

say "The wagon departs![paragraph break][if the player is on the lone wagon]After a short while you find yourself in...[end if]";

now the lone wagon is in the Train Station;

if the player is on the lone wagon:

now the lone wagon is lonely_s;

try looking;

stop the action;

otherwise:

say "Nothing happens. The wagon has reached the destination.".

Instead of getting off the lone wagon when the lone wagon is in the Crossroads, say "There's not that much space outside the wagon, and you risk being electrocuted by the rails."

Instead of pushing or pulling the lone wagon, say "The wagon must have some kind of mechanical brake working because, even if on wheels, it won't budge. Maybe it must be operated elseway."

Instead of pushing the lone wagon to a direction, try pushing the lone wagon.