Andromeda Apocalypse - Extended Edition — 54 of 97

Section 9 - The beast released

The Beast is an animal. "A deformed monstrosity is snarling in front of you[first time]. You can see its eye, its venomous, thousand-toothed mouth. You can see its hunger. As you move a step, it becomes aware of you and picks up your scent.[paragraph break]You had better hurry[only]." The printed name is "[one of]one eyed monstrosity[or]thousand-toothed nightmare[or]alien predator[or]creature[cycling]". Understand "beast/creature/monster/alien/nightmare/thousand-toothed/one-eyed/monstrosity/deformed/snarling/venomous" as the Beast. The description is "A hulking creature, still fast enough to overcome you in a twinkling. One eye, green like venom. One thousand teeth to compensate."

An animal can be hungry or famished or delayed. An animal is usually hungry.

Instead of attacking the Beast:

say "You try your wits against the monster. Too bad, you are not Gettare Rinors and the monsters has you for dinner.";

record "Slow Digestion" as achieved;

end the game in death.

Instead of attacking the Beast with something, try attacking the Beast.

Instead of taking the Beast, say "The beast has you, instead."

Instead of pushing or pulling the Beast, say "That would be less than courteous. And very, very dangerous, too."

Every turn when the Beast is delayed for two turns:

now the Beast is famished.

Every turn when the location of the Beast is the Location of the player:

if the Beast is hungry:

now the Beast is famished;

activate the Table of Beast Hints;

deactivate the Table of Escape Hints;

stop the action.

Every turn when the location of the Beast is the Location of the player for three turns:

say "With shocking speed, the beast jumps towards you.[paragraph break]You just have the time to be aware of the attack, before the thousand teeth in its mouth become your final sight.";

record "Slow Digestion" as achieved;

end the game in death.

Every turn when the player is in the Waste Area:

if the Beast is in LabTwo or the Beast is in Power Control Room:

say "The massive creature smells the entrance of the duct, its jaw dripping with ancient drool. After a while of trying to fit the narrow entrance, it barks a horrific growl and slowly walks away.";

record "Lynnea Rinors" as achieved;

now the beast is hungry;

move the Beast to Train Station.

Every turn when the Beast is famished:

if the location of the Beast is not the location of the player:

let the way be the best route from the location of Beast to the location of the player, using doors;

try the Beast going the way;

if the player is in Low_corr_SS and the jutting ledge is extended:

say "The beast lands on the extended ledge, finding a grip with its horrible claws.";

else if the player is in Low_corr_SS and the jutting ledge is retracted:

say "The creature jumps across the gap. You can see its only eye sparkling with hate, hunger...[paragraph break]... and then fear, when it misses the retracted ledge by a mere ten centimeters and falls down into the void.";

remove the Beast from play;

now the Beast is hungry;

deactivate the Table of Beast Hints;

[activate the Table of Ending Hints;]

record "Indiana Jones" as achieved;

otherwise:

say "[one of]The beast snares at you, its mouth dripping death and horror[or]The creature roars with anger. You can feel its hunger growing[or]The beast stares at you menacingly, its only eye a torment for the soul[at random]."

Before going west from Low_corr_SE when the Beast is famished:

now the beast is delayed.

Before entering the lone wagon when the beast is famished:

say "The creature jumps between you and the wagon, closing that escape route. You need to find somewhere else to go.";

stop the action.

Hell is a room.

Every turn when the location of the Beast is the location of the invisible nebula:

say "The creature snarls at you, its thousand-toothed mouth the sole plausible exit from this decaying world. Then, something happens. Its mouth begins filling with blood and before you can understand what is happening, the hulk is devoured by a billion tiny insects.[paragraph break]A hiss follows the invisible killer as it abandons the room, leaving you unscarred.";

remove the Beast from play;

now the Beast is hungry;

now the invisible nebula is in Hell;

deactivate the Table of Beast Hints;

[activate the Table of Ending Hints;]

record "Hellen Ripley" as achieved.

The smashed container is fixed in place. "The remains of a large container are scattered on the floor. It looks like it has exploded." The description is "It was a freezing container, now rendered into pieces." Understand "glass/metal/freezing/large/exploded/rendered/broken/remains" as the smashed container.

After printing the locale description of the High Corridor when the High Corridor is travelled:

say "As you pass through the big valve, it closes after you. Something tells you there's no turning back, at this point.";

now the steel valve is charged;

now the steel valve is closed;

now the High Corridor is untravelled.

After printing the locale description of the Train Station when the Train Station is travelled:

say "LOGAN://'Oh dear. It seems that dropping the main power has released our other only guest. Find sanctuary, Ektor Mastiff. That thing looks famished.'";

now the Train Station is untravelled.